Geekices

First own package on userrepository.eu

arch linux

Until now, userrepository.eu only used software from AUR. Today, to get me distracted from the flu and a respiratory infection I got a few days ago, I’ve finally created my first package for Arch Linux on my repository. It’s for a GTK web browser named Eoli and it builds from the master git branch.

Here’s the PKGBUILD at the time of writing:

# Maintainer: Bruno Miguel <omitted>
​
pkgname=eolie-git
_gitname=eolie
pkgver=da1899ff
pkgrel=1
pkgdesc="Simple GTK web browser for GNOME"
arch=('x86_64')
url="https://wiki.gnome.org/Apps/Eolie"
license=('GPL3')
depends=('gtkspell3' 'python-cairo' 'python-dateutil' 'python-gobject' 'webkit2gtk')
makedepends=('git' 'gobject-introspection' 'meson')
optdepends=('python-beautifulsoup4: Import html bookmarks'
            'python-crypto: Firefox Sync support'
            'python-fxa: Firefox Sync support'
            'python-pyopenssl: Show SSL certificates'
            'python-requests-hawk: Firefox Sync support')
source=("git+https://gitlab.gnome.org/World/eolie.git")
sha256sums=('SKIP')
​
pkgver() {
    cd "${_gitname}"
    ( set -o pipefail
        git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}
​
build() {
    arch-meson "${_gitname}" build
    ninja -C build
}
​
package() {
    DESTDIR="$pkgdir" meson install -C build
}
​

Every time there’s a new commit, it will grab that source and build it. This means you might get a less than stable browser, but also that you’ll always get the latest source.

Happy free softwareing! 🙂


Deixe uma resposta

O seu endereço de email não será publicado. Campos obrigatórios marcados com *

Este site utiliza o Akismet para reduzir spam. Fica a saber como são processados os dados dos comentários.